编程
您现在的位置:首页 >> 编程

ASP生成静态页面实例

一、技术分析

1、调用数据库模板;

2、信息输入页面传递信息;

3、接受信息值先保存数据库,再FSO生成文件;

4、FSO生成的文件放在某个以更新日期命名的子文件夹中,诸如 www.xxx.com/a/2013-5-20/200405201111.html。直接放在一个大文件夹下,随着时间的推移,文件会越来越多,管理比较困难。

5、通过FSO建立以当前系统日期命名的文件夹,如果文件夹存在的容错处理,在首行添加代码:On Error Resume Next,当然常规的做法是判断文件夹的有无。

<%

Set fso = Server.CreateObject("Scripting.FileSystemObject")

if (fso.FolderExists(Server.MapPath(folder))) then

'判断如果存在就不做处理

else

'判断如果不存在则建立新文件夹

fso.CreateFolder(Server.MapPath(folder))

end if

%>

以当前系统日期命名的文件夹,有一个问题,如果系统显示格式是XXXX/XX/XX就会出错,需要自己来写个函数进行格式化:

function makefolder(folder)

folder = folder

folder = replace(folder,"/","-")

folder = replace(folder," ","") 

makefolder=folder

end function

6、文件名的生成,写个函数以年月日时分秒命名:

<%

function makefilename(fname)

fname = fname '前fname为变量,后fname为函数参数引用

fname = replace(fname,"-","")

fname = replace(fname,"/","")

fname = replace(fname," ","") 

fname = replace(fname,":","")

fname = replace(fname,"PM","")

fname = replace(fname,"AM","")

fname = replace(fname,"上午","")

fname = replace(fname,"下午","")

makefilename=fname & ".shtml"

end function

引用函数则:<%fname = makefilename(now())%>

7、把生成文件的路径保存的数据库中,并且添加到相对应的记录集中。

8、模板技术和2HTML技术的结合:将模板中特殊代码的值替换为从表单接受过来的值,完成模板功能;将最终替换过的所有模板代码生成HTML文件。需要注意的是:替换应能将输入数据的格式或者支持UBB的代码彻底改变。

二、数据库设计

目前数据库的设计需要两个表:一个是存放模板数据的;一个是存放信息内容的。

1,建立新数据库pcfinal.mdb

2、设计新数据库表c_moban

字段m_id(自动编号,主关键字);字段m_html(备注类型)。

3、将下列完整的代码拷贝至m_html字段

<html>

<head>

<meta http-equiv="Content-Type" content="text/html; charset=hz">

<title>Cnbruce.Com | ASP2HTML TEST</title>

</head>

<body leftmargin="0" topmargin="0">

<table width="100%" height="100%" border="0" cellpadding="5" cellspacing="2">

<tr align="right" bgcolor="#CCCCCC">

<td height="20" colspan="2">$cntop{LogContent}lt;/td>

</tr>

<tr valign="top">

<td width="25%" bgcolor="#e5e5e5">$cnleft{LogContent}lt;/td>

<td width="74%" bgcolor="#f3f3f3">$cnright{LogContent}lt;/td>

</tr>

</table>

</body>

</html>

4、设计新数据库表c_news

字段c_id:自动编号,主关键字

字段c_title:文本类型,保存文章标题

字段c_content:备注类型,保存文章内容

字段c_filepath:文本类型,保持生成文件的路径地址

字段c_time:日期/时间类型,默认值:Now()

三、页面设计

1、建立一个存放HTML页的文件夹

在文件同一目录下,建立文件夹newsfile存放生成的HTML页面。

2、功能函数页面lib.asp

<%

'生成文件夹的函数

function makefolder(folder)

folder = folder

folder = replace(folder,"/","-")

folder = replace(folder," ","") 

makefolder=folder

end function 

'生成文件名的函数

function makefilename(fname)

fname = fname

fname = replace(fname,"-","")

fname = replace(fname,"/","")

fname = replace(fname," ","") 

fname = replace(fname,":","")

fname = replace(fname,"PM","")

fname = replace(fname,"AM","")

fname = replace(fname,"上午","")

fname = replace(fname,"下午","")

makefilename=fname & ".shtml"

end function 

'保持数据格式不变的函数

function HTMLEncode(fString)

fString = replace(fString, ">", ">")

fString = replace(fString, "<", "<")

fString = Replace(fString, CHR(32), " ")

fString = Replace(fString, CHR(13), "")

fString = Replace(fString, CHR(10) & CHR(10), "<br>")

fString = Replace(fString, CHR(10), "<br>")

HTMLEncode = fString

end function

%>

3、数据库连接页面conn.asp

完成数据库的字符串连接方法

<%

set conn = Server.CreateObject("ADODB.Connection")

connstr = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="&Server.MapPath("data/pcfinal.mdb")

conn.Open connstr

%>

4、信息输入页面add.html

表单action是跳转到addit.asp

<form action="addit.asp" method="post">

标题:<input type="text" name="c_title"><br>

内容:<br>

<textarea name="c_content" rows="8" cols="30"></textarea><br>

<input type="submit" value="添加">

<input type="reset" value="重写">

</form>

5、处理数据功能显示页面addit.asp

首先是处理接受过来的数据,并将值写入数据库;接着将模板代码进行引用,并将其中特殊代码转换为接受值,最终通过FSO生成HTML页面。

<%

'容错处理

On Error Resume Next

%>

<!--#include file="conn.asp" -->

<!--#include file="lib.asp" -->

<%'接受传递值

c_title=request.form("c_title")

c_content=request.form("c_content")

%>

<%'生成HTML文件名,建立文件夹,指定文件路径

fname = makefilename(now()) 'makefilename为自定义函数

folder = "newsfile/"& makefolder(date())&"/"

filepath = folder&fname

%>

<%'将接受值及路径保持至数据库表

sql = "select * from c_news"

Set rs = Server.CreateObject ("ADODB.Recordset")

rs.Open sql,conn,1,3

rs.addnew

rs("c_title")=c_title

rs("c_content")=c_content

rs("c_filepath")=filepath

rs.update

rs.close 

Set rs = Nothing

%>

<%'打开模板代码,并将其中特殊代码转变为接受值

sql1="select m_id,m_html from c_moban where m_id=1"

set rs1=Server.CreateObject("adodb.recordset")

rs1.open sql1,conn,1,1

mb_code=rs1("m_html")

rs1.close

set rs1=nothing

conn.close

set conn=nothing

c_title=htmlencode(c_title)

c_content=htmlencode(c_content)

mb_code=replace(mb_code,"$cntop{LogContent}",now())

mb_code=replace(mb_code,"$cnleft{LogContent}",c_title)

mb_code=replace(mb_code,"$cnright{LogContent}",c_content)

%>

<%'生成HTML页面

Set fso = Server.CreateObject("Scripting.FileSystemObject")

fso.CreateFolder(Server.MapPath(folder))

Set fout = fso.CreateTextFile(Server.MapPath(filepath))

fout.WriteLine mb_code

fout.close

%>

文章添加成功,<a href="showit.asp">浏览</a>

6、显示数据库表记录,并做指向HTML页的链接:showit.asp

<!--#include file="conn.asp" -->

<!--#include file="lib.asp" -->

<%

Set rs = Server.CreateObject ("ADODB.Recordset")

sql = "Select * from c_news order by c_id desc"

rs.Open sql,conn,1,1

%>

<%

if rs.EOF and rs.BOF then

response.write ("暂时还没有文章,<a href=add.html>添加</a>")

else

Do Until rs.EOF

%>

<table width="758" border="0" align="center" cellpadding="3" cellspacing="1" bgcolor="#000000">

<tr> 

<td width="159" align="right" bordercolor="#CCCCCC" bgcolor="#CCCCCC"><%=rs("c_time")%></td>

<td width="591" bordercolor="#f3f3f3" bgcolor="#f3f3f3"><a href=<%=rs("c_filepath")%> target="a_blank"><%=rs("c_title")%></a></td>

</tr>

<tr> 

<td valign="top" align="right" bordercolor="#ececec" bgcolor="#ececec">[<a href=del.asp?c_id=<%=rs("c_id")%>>删除</a>][<a href=change.asp?c_id=<%=rs("c_id")%>>更新</a>][<a href="add.html">添加</a>]</td>

<td valign="top" bordercolor="#FFFFFF" bgcolor="#FFFFFF"><%=htmlencode(rs("c_content"))%></td>

</tr>

</table><br>

<%

rs.MoveNext

Loop

end if

%>

<%

rs.close 

Set rs = Nothing

conn.close 

set conn=Nothing

%>

7、修改数据内容页change.asp

修改数据内容,同时也需要修改更新对应的HTML页面。修改其实就是重新生成文件,且文件名和之前一样,类似文件的覆盖。

<!--#include file="conn.asp" -->

<!--#include file="lib.asp" -->

<%id=request.querystring("c_id")%>

<%

if request.form("submit")="修改" then

c_title=request.form("c_title")

c_content=request.form("c_content")

c_id=request.form("c_id")

c_filepath=request.form("c_filepath")

Set rs = Server.CreateObject ("ADODB.Recordset")

sql = "Select * from c_news where c_id="&c_id

rs.Open sql,conn,3,2

rs("c_title")=c_title

rs("c_content")=c_content

rs("c_time")=now()

rs.update

rs.close 

Set rs = Nothing

%>

<%'打开模板代码,并将其中特殊代码转变为接受值

sql1="select m_id,m_html from c_moban where m_id=1"

set rs1=Server.CreateObject("adodb.recordset")

rs1.open sql1,conn,1,1

mb_code=rs1("m_html")

rs1.close

set rs1=nothing

conn.close

set conn=nothing

c_title=htmlencode(c_title)

c_content=htmlencode(c_content)

mb_code=replace(mb_code,"$cntop{LogContent}",now())

mb_code=replace(mb_code,"$cnleft{LogContent}",c_title)

mb_code=replace(mb_code,"$cnright{LogContent}",c_content)

%>

<%'生成HTML页面

Set fso = Server.CreateObject("Scripting.FileSystemObject")

Set fout = fso.CreateTextFile(Server.MapPath(c_filepath))

fout.WriteLine mb_code

fout.close

%>

<%response.redirect("showit.asp")%>

<%end if%>

<%

if id<>"" then

Set rs = Server.CreateObject ("ADODB.Recordset")

sql="select * from c_news where c_id="&id

rs.Open sql,conn,1,1

c_id=rs("c_id")

c_filepath=rs("c_filepath")

c_title=rs("c_title")

c_content=rs("c_content")

end if

%>

<form action="change.asp" method="post">

标题:<input type="text" name="c_title" value=<%=c_title%>><br>

内容:<br>

<textarea name="c_content" rows="8" cols="30"><%=c_content%></textarea><br>

<input type="submit" value="修改" name="submit">

<input type="reset" value="重写">

<input name="c_id" type="hidden" value="<%=id%>">

<input name="c_filepath" type="hidden" value="<%=c_filepath%>">

</form>

8、删除记录页del.asp

除了删除数据库表中的记录,与其对应的HTML页面也需删除。

<!--#include file="conn.asp" -->

<%

c_id = request.querystring("c_id")

sql = "Select * from c_news where c_id="&c_id

Set rs = Server.CreateObject ("ADODB.Recordset")

rs.Open sql,conn,2,3

filepath=rs("c_filepath")

Set fso = CreateObject("Scripting.FileSystemObject")

fso.DeleteFile(Server.mappath(filepath))

Set fso = nothing

rs.delete

rs.close 

Set rs = Nothing

conn.close

set conn=nothing

%>

<%response.redirect("showit.asp")%>